tbaMUD Continued development of the CircleMUD core

help global
GLOBALS GLOBAL-VARIABLES GLOBAL-VARS GVARS TRIGEDIT-GLOBALS TRIG-GLOBALS

Usage: global <variablename> 

   Global variables allow a room/mob/obj trigger variable to be used by another
trigger on the same room/mob/obj. i.e. a bribe trigger could global that the mob
has_been_bribed then when a player tries to leave the mobs leave trigger would
check the global variable to allow or prevent passage accordingly.

* To make a variable 'reachable' from other triggers it has to be made 'global'. 
* In this case I make a local known var %has_bribed_guard% and make it global. 
* It is a good idea to use this in conjunction with context.
set has_bribed_guard 1
global has_bribed_guard

Globals can be checked by varexists: if %actor.varexists(<variable>)%

Global variables should not be used when you want to remember something about a 
player. To save something to a players file for future use always use REMOTE. 

Examples: TSTAT 23612, 23613, 23614

See also: REMOTE, VARIABLES, CONTEXT
 > tstat 23612
Name: 'Lieutenant Door Bribe - M23608',  VNum: [23612], RNum: [ 2667]
Trigger Intended Assignment: Mobiles
Trigger Type: Bribe , Numeric Arg: 1, Arg list: None
Commands:
* By Welcor of The Builder Academy    tbamud.com 9091
wait 1
* The price is 400 coins to pass. Player must 'give 400 coin leader.'
if %amount% < 400
  say Did you really think I was that cheap, %actor.name%.
  snarl 
else
  * Context saves the global with the players ID so multiple players can bribe.
  context %actor.id%
  * Set the variable to a value, 1 for YES.
  set has_bribed_guard 1
  * Global it! You can now 'stat leader' and see it listed.
  global has_bribed_guard
  whisper %actor.name% Enter when you're ready. I'll lock the door behind you.
  unlock door
end
 > tstat 23613
Name: 'Lieutenant Door Bribe 2 - M23608',  VNum: [23613], RNum: [ 2668]
Trigger Intended Assignment: Mobiles
Trigger Type: Door , Numeric Arg: 100, Arg list: None
Commands:
* By Welcor of The Builder Academy    tbamud.com 9091
* Allows more than one instance of this trigger to run.
context %actor.id%
* Checks a global variable to see if this mob has been bribed. TSTAT 23612.
if %has_bribed_guard%
  * Let the player through, he's paid.
  return 1
  * Don't bother continuing the trig, just stop it.
  halt
end
* If the player tries to pick the lock catch him!
if %cmd% == pick
  * Stop them! Return 0 prevents the command from going through.
  return 0
  wait 1
  say No way, you don't fool me, %actor.name%.
  * If mob can see the player, kill him!
  if %actor.canbeseen%
    mkill %actor%
  end
end
 > tstat 23614
Name: 'Lieutenant Leave - 23608',  VNum: [23614], RNum: [ 2669]
Trigger Intended Assignment: Mobiles
Trigger Type: Leave , Numeric Arg: 100, Arg list: None
Commands:
* By Welcor of The Builder Academy    tbamud.com 9091
* If the player is trying to leave to the East.
if %direction% == east
  context %actor.id%
  * If they have bribed let them through and forget them.
  if %has_bribed_guard%
    unset has_bribed_guard
    * Let the command go through. Halt the trig, its over.
    return 1
    halt
  end
  * They haven't paid, stop them.
  %send% %actor% You try to leave, but %self.name% stops you.
  return 0